印刷設定（先頭ページのヘッダー・フッターを設定）DifferentFirstPageHeaderFooter, FirstPage

2015/10/19

先頭ページに別のヘッダーおよびフッターを設定

先頭ページのヘッダーおよびフッターの内容を設定するには、PageSetup.FirstPage プロパティを使用します。PageSetup.DifferetFirstPageHeaderFooter プロパティ に、True を指定することで、PageSetup.FirstPage プロパティ に設定した内容が有効になります。（※ Excel 2007 以降のバージョンでのみ使用できます。）

PageSetup.DifferentFirstPageHeaderFooter プロパティ

True に設定すると、先頭ページでは他のページと異なるヘッダーとフッターが使用されます。値の取得および設定が可能です。ブール型（Boolean）の値を使用します。

【書式】

＜取得＞
object.PageSetup.DifferentFirstPageHeaderFooter

＜設定＞
object.PageSetup.DifferentFirstPageHeaderFooter = boolean

引数・戻り値

object ・・・対象となる Worksheet オブジェクト を指定します。
boolean ・・・ True または、False を指定します。

PageSetup.FirstPage プロパティ

印刷対象の先頭ページのヘッダーおよびフッターを設定する際に使用する Page オブジェクト を取得します。
Page オブジェクト は、LeftHeader プロパティ、CenterHeader プロパティ などを使用して、各ヘッダー、フッター等を表す HeaderFooter オブジェクト を取得することができます。
HeaderFooter オブジェクト の Text プロパティ を使用して、各ヘッダー・フッターの文字列等の設定を行い、Picture プロパティ を使用して、画像の設定を行います。（印刷設定（ページごとに異なるヘッダー・フッターを設定）Page オブジェクト・HeaderFooter オブジェクトを参照）

【書式】

object.PageSetup.FirstPage

引数・戻り値

object ・・・対象となる Worksheet オブジェクト を指定します。

先頭ページだけ他のページと異なるヘッダーに設定した例

サンプルVBAソース

　
Sub Sample_HeaderFooter06()
    
    Dim w As Worksheet
    Dim pict As String
    
    Set w = ActiveSheet
    pict = CreateObject("WScript.Shell").SpecialFolders("MyDocuments") & "/sample01.jpg"
        
    'プリンタとの通信を遮断（印刷設定を高速化）
    Application.PrintCommunication = False
    
    With w.PageSetup
    
        '先頭ページのみ他ページと異なるヘッダーおよびフッターを設定する
        .DifferentFirstPageHeaderFooter = True
        
        
        '【先頭ページのヘッダー・フッターの設定】
        
        'ヘッダー中央に、文字列「[シート名] 先頭のページ」文字サイズ 24、色 青、太字、二重下線
        .FirstPage.CenterHeader.Text = "&24&K0000FF&B&E&A 先頭のページ"
        
        'フッター中央に、ページ数と総ページ数を表示
        .FirstPage.CenterFooter.Text = "&P / &N ページ"
                
                
        
        '【先頭ページ以外のヘッダー・フッターの設定】
        
        '表示する画像のパス＆名前
        .CenterHeaderPicture.Filename = pict

        '画像の比率を維持
        '※元画像との比率が異なる場合は Height の値が基準となる
        .CenterHeaderPicture.LockAspectRatio = msoTrue
        
        '元画像のサイズ 500
        .CenterHeaderPicture.Width = 500
        
        '元画像のサイズ 300
        .CenterHeaderPicture.Height = 150
        
        '画像の色（自動）
        .CenterHeaderPicture.ColorType = msoPictureAutomatic
        
        '画像の明度（ 50% ）
        .CenterHeaderPicture.Brightness = 0.5
        
        '画像のコントラスト（ 50% ）
        .CenterHeaderPicture.Contrast = 0.5

        'トリミングの範囲を設定
        .CenterHeaderPicture.CropTop = 0
        .CenterHeaderPicture.CropBottom = 250
        .CenterHeaderPicture.CropLeft = 0
        .CenterHeaderPicture.CropRight = 210
        
        'ヘッダー中央に画像を表示
        .CenterHeader = "&G"
        
        'フッター中央に、ページ数と総ページ数を表示
        .CenterFooter = "&P / &N ページ"
    
    End With

    'プリンタとの通信を再開
    Application.PrintCommunication = True
    
    'プレビュー表示
    w.PrintPreview
    
End Sub