罫線の設定（Borders プロパティ）

2015/07/25 2015/08/26

罫線の設定

罫線を一括（上下左右すべて）で設定するには、Borders プロパティを使用します。単体の Border オブジェクトを取得するには、Borders(index) プロパティを使用します。これにより、各罫線（上下左右他）それぞれの設定をすることができます。（index には、罫線を示す定数を指定します。）
設定する主な内容は以下のとおりです。

罫線の種類（LineStyle プロパティ）
罫線の太さ（Weight プロパティ）
罫線の色（Color プロパティ）
罫線の色（ThemeColor プロパティ）
罫線の基本色（ColorIndex プロパティ）
罫線の色の明るさ（TintAndShade プロパティ）

Borders.Item プロパティ

Borders のItem プロパティは、既定のプロパティになっているため、Item キーワードを省略することができます。

【書式】

object.Borders ( index )

object.Borders.Item ( index )

引数・戻り値

object ・・・対象となる Range オブジェクトを指定します。

index ・・・罫線を示す定数（XlBordersIndex 列挙）を指定します。

定数	値	内容
xlDiagonalDown	5	範囲内の各セルの左上隅から右下への罫線
xlDiagonalUp	6	範囲内の各セルの左下隅から右上への罫線
xlEdgeLeft	7	範囲内の左端の罫線
xlEdgeTop	8	範囲内の上側の罫線
xlEdgeBottom	9	範囲内の下側の罫線
xlEdgeRight	10	範囲内の右端の罫線
xlInsideVertical	11	範囲内のすべてのセルの垂直罫線
xlInsideHorizontal	12	範囲内のすべてのセルの水平罫線

上の罫線の種類を２重線に設定する
　Range(“C2”).Borders(xlEdgeTop).LineStyle = xlDouble

罫線（上下左右すべて）を破線に設定する
　Range(“C2”).Borders.LineStyle = xlDash

LineStyle プロパティ

罫線の種類を設定します。値の取得および設定が可能です。取得の場合、罫線の種類を表す定数の値を返します。

【書式】

object.LineStyle = const

引数・戻り値

object ・・・対象となる Borders オブジェクトを指定します。

const ・・・罫線の種類を表す定数（XlLineStyle 列挙）を指定します。

定数	値	内容
xlContinuous	1	実線
xlDashDot	4	一点鎖線
xlDashDotDot	5	ニ点鎖線
xlSlantDashDot	13	斜破線
xlDash	-4115	破線
xlDot	-4118	点線
xlDouble	-4119	2 本線
xlLineStyleNone	-4142	線なし

上記定数以外にも xlGray25、xlGray50、xlGray75、xlAutomatic も指定可能です。

Weight プロパティ

罫線の太さを設定します。値の取得および設定が可能です。取得の場合、罫線の太さを表す定数の値を返します。

【書式】

object.Weight = const

引数・戻り値

object ・・・対象となる Borders オブジェクトを指定します。
const ・・・罫線の太さを表す定数（XlBorderWeight 列挙）を指定します。

定数値内容

xlMedium -4138 普通

xlHairline 1 細線 (最も細い罫線)

xlThin 2 極細

xlThick 4 太線 (最も太い罫線)

罫線の色を設定する

Color プロパティ、ColorIndex プロパティ、ThemeColor プロパティ・TintAndShade プロパティなどを使用して罫線の色を設定します。いずれものプロパティも、値の取得および設定が可能です。

【書式】

object.Color = rgb

object.ColorIndex = c_index

object.ThemeColor = t_index

object.TintAndShade = single

引数・戻り値

object ・・・対象となる Borders オブジェクトを指定します。
rgb ・・・色を表す RGB 値を指定します。
　　⇒ 色の設定：Color プロパティ・RGB 関数
c_index ・・・カラーパレットの色を表す 1 ～ 56 のパレット番号を指定します。
　　⇒ 色の設定：ColorIndex プロパティ・Colors プロパティ
t_index ・・・テーマカラーの基本色を表すMsoThemeColorSchemeindex 列挙型の定数または値（1 ～ 12）を指定します。
　　⇒ 色の設定：ThemeColor プロパティ・TintAndShade プロパティ
single ・・・色の明るさを -1（暗い） ～ 1（明るい）で指定します。
　　⇒ 色の設定：ThemeColor プロパティ・TintAndShade プロパティ

Borders プロパティ使用例

サンプルVBAソース

　
Sub Sample_Borders()

    Dim myRng As Range
    
    'セル「B2:I11」
    Set myRng = Range("B2:I11")
    
    With myRng.Borders
        
        '範囲内全ての罫線 黒・実線・普通線
        .Color = rgbBlack
        .LineStyle = xlContinuous
        .Weight = xlMedium
        
        '範囲内の水平罫線のみ 赤・ニ点鎖線・細線
        .Item(xlInsideHorizontal).Color = rgbRed
        .Item(xlInsideHorizontal).LineStyle = xlDashDotDot
        .Item(xlInsideHorizontal).Weight = xlHairline
        
        '範囲上のみ 青・太線
        .Item(xlEdgeTop).Color = rgbBlue
        .Item(xlEdgeTop).Weight = xlThick
        
        '範囲下のみ 青・太線
        .Item(xlEdgeBottom).Color = rgbBlue
        .Item(xlEdgeTop).Weight = xlThick
        
        '範囲左のみ 緑・太線
        .Item(xlEdgeLeft).Color = rgbGreen
        .Item(xlEdgeLeft).Weight = xlThick
        
        '範囲右のみ 緑・太線
        .Item(xlEdgeRight).Color = rgbGreen
        .Item(xlEdgeRight).Weight = xlThick

    End With
    
    'セル「B8:B11」に左下から右上の斜罫線
    With Range("B8:B11").Borders(xlDiagonalUp)
        
        '二重線
        .LineStyle = xlDouble
        
        '色の設定
        .Color = RGB(220, 150, 20)
        
        '太さ（普通）
        .Weight = xlMedium
        
    End With
        

End Sub