ハイパーリンク（Hyperlink オブジェクト）

2015/09/20 2015/09/21

Hyperlink オブジェクト

Hyperlinks コレクション のメンバーです。セル範囲やワークシートは、複数のハイパーリンクを持つことができます。単体の Hyperlink オブジェクトを取得するには、Hyperlinks(index) プロパティを使用します。引数 index には、ハイパーリンク番号を指定します。
Hyperlink オブジェクト のメソッドに関しては、ハイパーリンク（Hyperlink オブジェクトのメソッド）、Hyperlinksに関しては、ハイパーリンク（Hyperlinks オブジェクト）を参照してください。

【書式】

object.Hyperlink

引数・戻り値

object ・・・対象となる Shape オブジェクト または、Range オブジェクトを指定します。

Hyperlink オブジェクトのプロパティ

Hyperlink.Name プロパティ

【書式】

object.Hyperlink.Name

引数・戻り値

object ・・・対象となる Range オブジェクト または、Shape オブジェクトを指定します。
オブジェクトの名前を表す文字列型（String）の値を返します。（セルに挿入されたハイパーリンクの場合は、TextToDisplay プロパティ と同じ値、図形の場合は、Address プロパティ と同じ値になるようです。）

Hyperlink.Range プロパティ

【書式】

object.Hyperlink.Range

引数・戻り値

object ・・・対象となる Range オブジェクト または、Shape オブジェクトを指定します。
指定されたハイパーリンクが挿入されているセル範囲を Range オブジェクト で返します。

Hyperlink.Address プロパティ

【書式】

object.Hyperlink.Address

引数・戻り値

object ・・・対象となる Range オブジェクト または、Shape オブジェクトを指定します。
ハイパーリンクのアドレスを取得または、設定します。

Hyperlink.SubAddress プロパティ

【書式】

object.Hyperlink.SubAddress

引数・戻り値

object ・・・対象となる Range オブジェクト または、Shape オブジェクトを指定します。
任意のセルへのハイパーリンクが設定されている場合のセルのアドレスを取得または設定します。
　「Book1.xlsx」の「Sheet1」の「B5」セルの場合：”[Book1.xlsx]Sheet1!B5″

Hyperlink.TextToDisplay プロパティ

【書式】

object.Hyperlink.TextToDisplay

引数・戻り値

object ・・・対象となる Range オブジェクト または、Shape オブジェクトを指定します。
ハイパーリンクの表示テキスト（セルに表示される文字列）を取得または設定します。既定値は、ハイパーリンクのアドレスです。

Hyperlink.ScreenTip プロパティ

【書式】

object.Hyperlink.ScreenTip

引数・戻り値

object ・・・対象となる Range オブジェクト または、Shape オブジェクトを指定します。
ハイパーリンク上をマウスポインターで指した場合に表示されるヒントを取得または設定をします。

Hyperlink.Type プロパティ

【書式】

object.Hyperlink.Type

引数・戻り値

object ・・・対象となる Range オブジェクト または、Shape オブジェクトを指定します。

ハイパーリンクの種類を表す値（MsoHyperlinkType 列挙型 の定数）を取得または設定します。

定数	値	内容
msoHyperlinkRange	0	ハイパーリンクは、セルRange オブジェクトに適用されます
msoHyperlinkShape	1	ハイパーリンクは、図形Shape オブジェクトに適用されます

Hyperlink.EmailSubject プロパティ

【書式】

object.Hyperlink.EmailSubject

引数・戻り値

object ・・・対象となる Range オブジェクト または、Shape オブジェクトを指定します。
index ・・・
指定されたハイパーリンクのリンク先が電子メールの場合、メールの件名を表す文字列を設定します。件名はハイパーリンクのアドレスに追加されます。値の取得および設定が可能です。
また、このプロパティの値は、同じ Hyperlink オブジェクトでの Address プロパティで設定される電子メールの件名よりも優先されます。

Hyperlink オブジェクト使用例

サンプルVBAソース

　
Sub Sample_HyperlinksAdd()


    With ActiveSheet

        '「B3」セルにハイパーリンクを挿入
        .Hyperlinks.Add Anchor:=.Range("B3"), _
                        Address:="http://www.yahoo.co.jp/", _
                        ScreenTip:="Yahoo! のトップヘージへ移動", _
                        TextToDisplay:="Yahoo! JAPAN"


        '図形の挿入
        .Shapes.AddShape msoShapeNoSymbol, 150, 100, 220, 125

        '図形にハイパーリンクを挿入
        .Hyperlinks.Add Anchor:=.Shapes.Item(1), _
                        Address:="http://www.google.co.jp", _
                        ScreenTip:="Google 検索へ移動", _
                        TextToDisplay:="図形のハイパーリンク"


        '「E3」セルに「別シートのセル」へのハイパーリンクを挿入
        .Hyperlinks.Add Anchor:=.Range("E3"), _
                        Address:="", _
                        SubAddress:="Sheet2!C3", _
                        ScreenTip:="シート２「C3」へ移動します！"


        '「H3」セルに「電子メール」へのハイパーリンクを挿入
        .Hyperlinks.Add Anchor:=.Range("H3"), _
                        Address:="mailto:test@example.co.jp?subject=テストメール！", _
                        ScreenTip:="メールソフトを起動します！", _
                        TextToDisplay:="E-MAIL"

    End With


End Sub

Sub Sample_HyperlinksAdd()

With ActiveSheet

'「B3」セルにハイパーリンクを挿入

.Hyperlinks.Add Anchor:=.Range("B3"), _

Address:="http://www.yahoo.co.jp/", _

ScreenTip:="Yahoo! のトップヘージへ移動", _

TextToDisplay:="Yahoo! JAPAN"

'図形の挿入

.Shapes.AddShape msoShapeNoSymbol, 150, 100, 220, 125

'図形にハイパーリンクを挿入

.Hyperlinks.Add Anchor:=.Shapes.Item(1), _

Address:="http://www.google.co.jp", _

ScreenTip:="Google 検索へ移動", _

TextToDisplay:="図形のハイパーリンク"

'「E3」セルに「別シートのセル」へのハイパーリンクを挿入

.Hyperlinks.Add Anchor:=.Range("E3"), _

Address:="", _

SubAddress:="Sheet2!C3", _

ScreenTip:="シート２「C3」へ移動します！"

'「H3」セルに「電子メール」へのハイパーリンクを挿入

.Hyperlinks.Add Anchor:=.Range("H3"), _

Address:="mailto:test@example.co.jp?subject=テストメール！", _

ScreenTip:="メールソフトを起動します！", _

TextToDisplay:="E-MAIL"

End With

End Sub

　
Sub Sample_Hyperlink()

    Dim str As String, i As Long

    str = "ハイパーリンクの数：" & ActiveSheet.Hyperlinks.Count & vbCrLf
    
    On Error Resume Next
        
    For i = 1 To ActiveSheet.Hyperlinks.Count
        
        str = str & vbCrLf & "ハイパーリンク【" & i & "】" & vbCrLf
        str = str & "　Name　：" & vbTab & ActiveSheet.Hyperlinks.Item(i).Name & vbCrLf
        str = str & "　Address：" & vbTab & ActiveSheet.Hyperlinks.Item(i).Address & vbCrLf
        str = str & "　SubAddress：" & vbTab & ActiveSheet.Hyperlinks.Item(i).SubAddress & vbCrLf
        str = str & "　ScreenTip：" & vbTab & ActiveSheet.Hyperlinks.Item(i).ScreenTip & vbCrLf
        str = str & "　TextToDisplay：" & vbTab & ActiveSheet.Hyperlinks.Item(i).TextToDisplay & vbCrLf
        str = str & "　Rangeアドレス：" & vbTab & ActiveSheet.Hyperlinks.Item(i).Range.Address & vbCrLf
        str = str & "　EmailSubject：" & vbTab & ActiveSheet.Hyperlinks.Item(i).EmailSubject & vbCrLf
        str = str & "　HyperLink種類：" & vbTab & _
            IIf(ActiveSheet.Hyperlinks.Item(i).Type, "図形", "セル") & vbCrLf
    
    Next i
    

    MsgBox str
    
    
End Sub