印刷設定（ヘッダーに画像を指定）LeftHeaderPicture, CenterHeaderPicture, RightHeaderPicture

2015/10/18

ヘッダーに画像を表示するには

LeftHeaderPicture プロパティ、CenterHeaderPicture プロパティ、RightHeaderPicture プロパティ を使用して、Graphic オブジェクト を取得します。
Graphic オブジェクト で、表示する画像ファイルを取得（Filename プロパティ）します。また、その他、画像ファイルのさまざまな設定を行います。（詳細は、印刷設定（ヘッダー・フッターに画像を設定）Graphic オブジェクトを参照してください。）
実際に画像を表示するには、LeftHeader プロパティ、CenterHeader プロパティ、RightHeader プロパティ などに、VBA コードの「&G」を設定します。（VBA コード に関しては、印刷設定（ヘッダー／フッター）書式コード・VBAコードを参照してください。）

PageSetup.LeftHeaderPicture プロパティ

PageSetup.LeftHeaderPicture プロパティを使用して、左ヘッダーに画像を表示するための設定を行います。実際に画像を表示するには、PageSetup.LeftHeader プロパティ に、VBA コード「&G」を指定します。

【書式】

object.PageSetup.LeftHeaderPicture

引数・戻り値

object ・・・対象となる Worksheet オブジェクト を指定します。
LeftHeaderPicture プロパティで、Graphic オブジェクトを取得し、画像の設定を行います。

（例）画像（C:\Sample.bmp）を左ヘッダーに表示する設定
　　With Activesheet.PageSetup
　　　　LeftHeaderPicture.Filename = “C:\Sample.bmp”
　　　　LeftHeader = “&G”
　　End With

PageSetup.CenterHeaderPicture プロパティ

PageSetup.CenterHeaderPicture プロパティを使用して、ヘッダー中央に画像を表示するための設定を行います。実際に画像を表示するには、PageSetup.CenterHeader プロパティ に、VBA コード「&G」を指定します。

【書式】

object.PageSetup.CenterHeaderPicture

引数・戻り値

object ・・・対象となる Worksheet オブジェクト を指定します。
CenterHeaderPicture プロパティで、Graphic オブジェクトを取得し、画像の設定を行います。

（例）画像（C:\Sample.bmp）をヘッダー中央に表示する設定
　　With Activesheet.PageSetup
　　　　CenterHeaderPicture.Filename = “C:\Sample.bmp”
　　　　CenterHeader = “&G”
　　End With

PageSetup.RightHeaderPicture プロパティ

PageSetup.RightHeaderPicture プロパティを使用して、右ヘッダーに画像を表示するための設定を行います。実際に画像を表示するには、PageSetup.RightHeader プロパティ に、VBA コード「&G」を指定します。

【書式】

object.PageSetup.RightHeaderPicture

引数・戻り値

object ・・・対象となる Worksheet オブジェクト を指定します。
RightHeaderPicture プロパティで、Graphic オブジェクトを取得し、画像の設定を行います。

（例）画像（C:\Sample.bmp）を右ヘッダーに表示する設定
　　With Activesheet.PageSetup
　　　　RightHeaderPicture.Filename = “C:\Sample.bmp”
　　　　RightHeader = “&G”
　　End With

ヘッダーに画像を設定する

サンプルVBAソース

　
Sub Sample_HeaderFooter03()
    
    Dim w As Worksheet
    Dim pict As String
    
    Set w = ActiveSheet
    pict = CreateObject("WScript.Shell").SpecialFolders("MyDocuments") & "/sample01.jpg"
        
    'プリンタとの通信を遮断（印刷設定を高速化）
    Application.PrintCommunication = False
    
    With w.PageSetup
        
        '表示する画像のパス＆名前
        .CenterHeaderPicture.Filename = pict
        
        '画像の比率を維持
        '※元画像との比率が異なる場合は Height の値が基準となる
        .CenterHeaderPicture.LockAspectRatio = msoTrue
        
        '元画像のサイズ 500
        .CenterHeaderPicture.Width = 500
        
        '元画像のサイズ 300
        .CenterHeaderPicture.Height = 150
        
        '画像の色（自動）
        .CenterHeaderPicture.ColorType = msoPictureAutomatic
        
        '画像の明度（ 50% ）
        .CenterHeaderPicture.Brightness = 0.5
        
        '画像のコントラスト（ 50% ）
        .CenterHeaderPicture.Contrast = 0.5

        'トリミングの範囲を設定
        .CenterHeaderPicture.CropTop = 0
        .CenterHeaderPicture.CropBottom = 250
        .CenterHeaderPicture.CropLeft = 0
        .CenterHeaderPicture.CropRight = 210
        
        'ヘッダー中央に画像を表示
        .CenterHeader = "&G"
        
    End With

    'プリンタとの通信を再開
    Application.PrintCommunication = True
    
    'プレビュー表示
    w.PrintPreview
    
End Sub