ユーザー設定のビュー（CustomViews プロパティ）

2015/12/10 2015/12/11

ユーザー設定のビュー

CustomViews コレクションは、ユーザー設定ビューを表し、CustomViews プロパティを使用して取得することができます。また、CustomView オブジェクトは、登録されている各ビューを表し、取得するには、CustomViews(index) プロパティを使用します。

【書式】

＜CustomViews コレクションの取得＞
object.CustomViews

引数・戻り値

object ・・・対象となる Workbook オブジェクトを指定します。
index ・・・登録されているビューの名前またはインデックス番号を指定します。

CustomViews の主なメソッド

CustomViews.Add メソッド

【書式】

object.Add ( viewname, printsettings, rowcolsettings )

引数・戻り値

object ・・・対象となる CustomViews コレクションを指定します。
viewname ・・・新しいビューの名前を指定します。省略不可。
printsettings ・・・ユーザー設定のビューに印刷設定を含める場合は、True を指定します。省略時は、True を指定したことになります。
rowcolsettings ・・・ユーザー設定のビューに非表示の行や列の設定（フィルター情報を含む）を含める場合は、True を設定します。省略時は、True を指定したことになります。
戻り値・・・新しいユーザー設定のビューを表す CustomView オブジェクト。

CustomViews.Item メソッド

CustomViews コレクション から単一の CustomView オブジェクト を取得します。

【書式】

object[.Item] ( index )

引数・戻り値

object ・・・対象となる CustomViews コレクションを指定します。
index ・・・登録されているビューの名前またはインデックス番号を指定します。

Item は、省略可能です。

CustomViews.Item (index )プロパティ の詳細に関しては、ユーザー設定のビュー（CustomView オブジェクト）を参照してください。

CustomViews の主なプロパティ

CustomViews.Count プロパティ

【書式】

object.Count

引数・戻り値

object ・・・対象となる CustomViews コレクションを指定します。
戻り値・・・コレクションに含まれるオブジェクトの数（つまり登録されているビューの数）を表す長整数型（Long）の値。

CustomViews プロパティ使用例

サンプルVBAソース

　
Sub Sample01_CustomViews()

    Worksheets("Sheet1").Select
    
    Dim v As CustomView
    
    'すべてのユーザー設定ビューを削除
    With ActiveWorkbook
        
        For Each v In .CustomViews
                    
            v.Delete
                     
        Next v
    
    End With
    
    
    '新規ビューの作成 1
    ActiveWorkbook.CustomViews.Add "テスト結果一覧表", True, True
    
    'D,E,F 列を非表示
    Columns("D:E").EntireColumn.Hidden = True
    '新規ビューの作成 2
    ActiveWorkbook.CustomViews.Add ViewName:="テスト結果（英・国・数）", _
                                   PrintSettings:=True, _
                                   RowColSettings:=True

End Sub

Sub Sample02_CustomViews()

    '設定されているユーザー設定ビューの名前を表示
    Dim CustomViewsNames As String
    Dim i As Integer
    
    With ActiveWorkbook.CustomViews
    
        For i = 1 To .Count
        
            CustomViewsNames = CustomViewsNames & .Item(i).Name & vbCrLf
        
        Next i
    
    End With
            
    MsgBox CustomViewsNames

End Sub

Sub Sample03_CustomViews()

    'ユーザー設定ビューを表示
    ActiveWorkbook.CustomViews.Item(1).Show

End Sub

Sub Sample04_CustomViews()

    'ユーザー設定ビューを表示
    ActiveWorkbook.CustomViews("テスト結果（英・国・数）").Show

End Sub