テキストファイル：データを書き込む（Print # ステートメント）

2016/01/07

Print # ステートメント

Open ステートメントをシーケンシャル出力モード（Output）または、追加モード（Append）で開いたファイルにデータを書き込みます。Write # ステートメントとは違い、データに、区切り文字やダブルクォーテーション（”）は挿入されません。１行単位で、データを書き込みます。

【構文】

Print #filenumber, [ outputlist ]

引数・戻り値

filenumber ・・・ Open ステートメントで、割り当てられたファイル番号を指定します。
outputlist ・・・ファイルに書き込む内容を指定します。また、Spc 関数、Tab 関数を使用することができます。

引数 outputlist の最後の文字がファイルに書き込まれた後に、改行文字のキャリッジリターンとラインフィード（ Chr(13) + Chr(10) ）が挿入されます。この時、末尾にセミコロン（;）を付加すると改行コードは書き込まれません。

引数 outputlist を省略するとファイルには空白行が書き込まれます。このとき、直前のカンマ（,）は省略できません。

Print # ステートメントで書き込まれたデータは、通常、Line Input # ステートメントまたは Input 関数を使用してファイルから読み取られます。

Spc 関数

Print # ステートメント と共に使用し、引数 n に指定した分のスペースを出力します。

【書式】

Spc ( n )

引数・戻り値

n ・・・スペースの数を指定します。

Tab 関数

Print # ステートメント と共に使用し、引数 n に指定した位置に移動します。

【書式】

Tab ( n )

引数・戻り値

n ・・・出力位置を指定します（省略可）。

Print # ステートメント使用例

サンプルVBAソース 1

　
Sub Sample_Print_InputMode()

    '１行ごとにデータを書き込む（Output モード・Print # ステートメント）
    'ファイルが存在しない場合は新規作成、ファイルが既に存在する場合は、内容を上書き

    '「Sheet2」のデータを元に、ファイルに、HTMLを書き込みます。
        
    Dim w As Worksheet
    Dim myRng As Range
    Dim FileName As String
    Dim FNum As Integer
    Dim i As Long
    Dim j As Long
    
    Set w = Worksheets("Sheet2")
    Set myRng = w.Range("A1").CurrentRegion
    
    FileName = "C:\Documents\mydata\file02.html"
    FNum = FreeFile     'ファイル番号取得
    
    'ファイルを開く（Output モード）
    Open FileName For Output As #FNum
    
        Print #FNum, "<!DOCTYPE html>"
        Print #FNum, "<html lang=""ja"">"
        Print #FNum, Spc(2); "<head>"
        Print #FNum, Spc(4); "<title>成績表</title>"
        Print #FNum, Spc(2); "</head>"
        Print #FNum, Spc(2); "<body>"
        Print #FNum, Spc(4); "<h1>期末テスト結果</h1>"
        Print #FNum, Spc(4); "<table border="; 1; " cellspacing="; 0; " cellpadding="; 2; ">"

        For i = 1 To myRng.Rows.Count
            
            Print #FNum, Spc(6); "<tr>";
            
            For j = 1 To myRng.Columns.Count
                
                If i = 1 Then
                    Print #FNum, "<th>" & myRng(i, j) & "</th>";
                Else
                    Print #FNum, "<td>" & myRng(i, j) & "</td>";
                End If

            Next j
            
            Print #FNum, "</tr>"
        
        Next i
        
        Print #FNum, Spc(4); "</table>"
        Print #FNum, Spc(2); "</body>"
        Print #FNum, "</html>"
        
    Close #FNum

End Sub

Sub Sample_Print_InputMode()

'１行ごとにデータを書き込む（Output モード・Print # ステートメント）

'ファイルが存在しない場合は新規作成、ファイルが既に存在する場合は、内容を上書き

'「Sheet2」のデータを元に、ファイルに、HTMLを書き込みます。

Dim w As Worksheet

Dim myRng As Range

Dim FileName As String

Dim FNum As Integer

Dim i As Long

Dim j As Long

Set w = Worksheets("Sheet2")

Set myRng = w.Range("A1").CurrentRegion

FileName = "C:\Documents\mydata\file02.html"

FNum = FreeFile 'ファイル番号取得

'ファイルを開く（Output モード）

Open FileName For Output As #FNum

Print #FNum, "<!DOCTYPE html>"

Print #FNum, "<html lang=""ja"">"

Print #FNum, Spc(2); "<head>"

Print #FNum, Spc(4); "<title>成績表</title>"

Print #FNum, Spc(2); "</head>"

Print #FNum, Spc(2); "<body>"

Print #FNum, Spc(4); "<h1>期末テスト結果</h1>"

Print #FNum, Spc(4); "<table border="; 1; " cellspacing="; 0; " cellpadding="; 2; ">"

For i = 1 To myRng.Rows.Count

Print #FNum, Spc(6); "<tr>";

For j = 1 To myRng.Columns.Count

If i = 1 Then

Print #FNum, "<th>" & myRng(i, j) & "</th>";

Else

Print #FNum, "<td>" & myRng(i, j) & "</td>";

End If

Next j

Print #FNum, "</tr>"

Next i

Print #FNum, Spc(4); "</table>"

Print #FNum, Spc(2); "</body>"

Print #FNum, "</html>"

Close #FNum

End Sub

サンプルVBAソース 1 実行結果

「Sheet 2」の内容

サンプルVBAソース 1 を実行して作成された「file02.html」の内容

サンプルVBAソース 2

　
Sub Sample_Print_InputMode2()

    '１行ごとにデータを書き込む（Output モード・Print # ステートメント）

    Dim FileName As String
    Dim FNum As Integer
    Dim myDate1 As Date
    Dim myDate2 As Date
    Dim myBool As Boolean
    Dim myNull
    Dim myError
    
    FileName = "C:\Documents\mydata\test.txt"
    FNum = FreeFile
    myDate1 = #9/25/2015#
    myDate2 = Date
    myBool = True
    myNull = Null
    myError = CVErr(32767)
    
    'ファイルをシーケンシャル出力モード（Output）で開く
    Open FileName For Output As FNum
    
    'ファイルへ書き込み
    
    Print #FNum, "ファイルへ書き込みをします。"          '文字列書き込み
    Print #FNum,                                      '空白行の挿入
    Print #FNum, Spc(10); "左に半角スペース１０個分"     'スペース10挿入（Spc 関数）
    Print #FNum, "12345678901234567890"               '数値
    Print #FNum, "abcdefghijklmno"                    'アルファベット
    Print #FNum, "abcde"; Tab(11); "klmno"            '途中にタブを挿入（Tab 関数）
    Print #FNum, "日付："; myDate1; Tab; myDate2       '日付　タブ　日付
    Print #FNum, "myBool："; myBool                   'ブール型の値の挿入
    Print #FNum, "myNull："; myNull                   'Null値の挿入
    Print #FNum, "myError："; myError                 'エラー値の挿入
    
    'ファイルを閉じる
    Close #FNum
    
End Sub

Sub Sample_Print_InputMode2()

'１行ごとにデータを書き込む（Output モード・Print # ステートメント）

Dim FileName As String

Dim FNum As Integer

Dim myDate1 As Date

Dim myDate2 As Date

Dim myBool As Boolean

Dim myNull

Dim myError

FileName = "C:\Documents\mydata\test.txt"

FNum = FreeFile

myDate1 = #9/25/2015#

myDate2 = Date

myBool = True

myNull = Null

myError = CVErr(32767)

'ファイルをシーケンシャル出力モード（Output）で開く

Open FileName For Output As FNum

'ファイルへ書き込み

Print #FNum, "ファイルへ書き込みをします。" '文字列書き込み

Print #FNum, '空白行の挿入

Print #FNum, Spc(10); "左に半角スペース１０個分" 'スペース10挿入（Spc 関数）

Print #FNum, "12345678901234567890" '数値

Print #FNum, "abcdefghijklmno" 'アルファベット

Print #FNum, "abcde"; Tab(11); "klmno" '途中にタブを挿入（Tab 関数）

Print #FNum, "日付："; myDate1; Tab; myDate2 '日付　タブ　日付

Print #FNum, "myBool："; myBool 'ブール型の値の挿入

Print #FNum, "myNull："; myNull 'Null値の挿入

Print #FNum, "myError："; myError 'エラー値の挿入

'ファイルを閉じる

Close #FNum

End Sub

サンプルVBAソース 2 実行結果

サンプルVBAソース 2 を実行して作成された「test.txt」の内容

サンプルVBAソース 3

サンプルVBAソース 2 を実行して作成された「test.txt」にデータを追加

　
Sub Sample_Print_AppendMode()

    '１行ごとにデータを書き込む（Append モード・Print # ステートメント）

    Dim FileName As String
    Dim FNum As Integer
    Dim myDate1 As Date
    Dim myDate2 As Date
    
    FileName = "C:\Documents\mydata\test.txt"
    FNum = FreeFile
    
    myDate1 = Now
    myDate2 = Time
    
    '追加モード（Append）で開く
    Open FileName For Append As FNum
    
    'ファイルへ追加で書き込み
    Print #FNum,                                       '空白行の挿入
    Print #FNum, "ファイルへデータ追加します。"          '文字列書き込み
    Print #FNum, "日付時刻："; myDate1                  '日付時刻
    Print #FNum, "時刻："; myDate2                     '時刻
    
    'ファイルを閉じる
    Close #FNum

End Sub