データベース（Oracle）に接続する（ODBC を使用）

2017/09/28

ODBC接続（ADO）

ADOで、ODBC（Open Database Connectivity）ドライバを使って、Oracle データベースへ接続する場合、Open メソッド の ConnectionString プロパティに、ODBCドライバ名を指定する接続文字列を記述します。
　　→　OLE DB による接続
　　→　oo4o による接続

接続文字列

【ConnectionString（ADO）に設定する文字列】

＜ドライバ名・ネットサービス名を指定する場合＞
DRIVER = {Microsoft ODBC for Oracle};
CONNECTSTRING = NetServiceName;
UID = UserName;
PWD = PassWord;

＜データソース名を指定する場合＞
DSN = DSN;UID = UserName;PWD = PassWord;

引数・戻り値

NetServiceName ・・・ tnsnames.ora ファイルのネットサービス名を指定します。
UserName ・・・ユーザー名を指定します。
PassWord ・・・パスワードを指定します。
DSN ・・・データソース名をしていします。

Oracle 接続（ODBC）

サンプルVBAソース

　
Sub Sample_ODBC_oracle()
    
    Dim oraCon As ADODB.Connection
    Dim oraRs As ADODB.Recordset
    Dim constr As String
    Dim strSQL As String
    Dim col As Long
    Dim row As Long
    
    Const DRIVER = "{Microsoft ODBC for Oracle}"    'ドライバ名（Microsoft社製）
    'Const DRIVER = "{Oracle in OraDb11g_home1}"    'ドライバ名（Oracle社製）
    Const NETSERVICENAME = "hpdb1"                  'tnsnames.ora ファイルのネットサービス名'
    Const DSN = "ORACL_hpdb1"                       'データソース名
    Const USERNAME = "uhpdb1"                       '接続するデータベースのユーザー名
    Const PASSWORD = "uhpdb1"                       'パスワード
    
    Set oraCon = New ADODB.Connection
    
    'ドライバー名・ネットサービス名を指定する場合
    constr = "DRIVER=" & DRIVER
    constr = constr & ";CONNECTSTRING=" & NETSERVICENAME
    constr = constr & ";UID=" & USERNAME
    constr = constr & ";PWD=" & PASSWORD & ";"
    
    'データソース名を指定する場合
'    constr = "DSN=" & DSN
'    constr = constr & ";UID=" & USERNAME
'    constr = constr & ";PWD=" & PASSWORD
    
    oraCon.ConnectionString = constr
    oraCon.Open
    
    strSQL = "select * from table01 order by id desc"
    
    Set oraRs = New ADODB.Recordset
    oraRs.Open strSQL, oraCon
    
    With Worksheets("oracle_odbc")
    
        .Cells.Clear
    
        'フィールド名
        For col = 0 To oraRs.Fields.Count - 1
            .Cells(1, col + 1) = oraRs(col).Name
        Next col
    
        'レコード
        Do Until oraRs.EOF
            For col = 0 To oraRs.Fields.Count - 1
                .Cells(row + 2, col + 1) = oraRs(col).Value
            Next col
            row = row + 1
            oraRs.MoveNext
        Loop
    
    End With
    
    oraRs.Close
    oraCon.Close
    Set oraCon = Nothing
    
End Sub