レコードの削除（ADO）Delete メソッド

サイト管理人

7年前

データベースのレコードを削除する

Delete メソッド

カレントレコードを削除します。

【書式】

object.Delete

引数・戻り値

object ・・・対象となる Recordset オブジェクトを指定します。

レコードを削除する場合、Recordset オブジェクトのOpen メソッドの引数 LockType には、adLockOptimistic または adLockPessimistic を指定します。（Recordset を開く時に使うロックの種類に関しては、データベース（Access 等）に接続（ADO）を参照して下さい。）

カレントレコードは、レコード削除後も「削除されたレコード」として存在するレコードになります。この状態で、カレントレコードに対して処理を行うと、エラーが発生します。（ MoveNext メソッド 等を使ってカーソルを移動する必要があります。）

Delete メソッド使用例

サンプルVBAソース

　
Sub Sample_Delete()
    
    '参照設定:Microsoft ActiveX Data Objects 6.1 Library
    
    Dim cn As ADODB.Connection
    Dim rs As ADODB.Recordset
    Dim constr As String
    Dim DBFile As String
    Dim i As Long
    Dim j As Long
    
    DBFile = ActiveWorkbook.Path & "\mydb1.accdb"
    constr = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & DBFile
    
    Set cn = New ADODB.Connection
    cn.ConnectionString = constr
    cn.Open
    
    Set rs = New ADODB.Recordset
    With rs
        
        'テーブルを開く
        .Source = "テーブル1"
        .ActiveConnection = cn
        .CursorType = adOpenKeyset      'キーセットカーソル使用
        .LockType = adLockPessimistic   'レコード単位排他的ロック
        .Open
        
        'ID=1 のレコードにカーソルを移動
        .Find "ID = 1", 0, adSearchForward
        
        'カレントレコードを削除
        .Delete
    
    End With
    
    With Worksheets("Sheet1")
        rs.MoveFirst
        i = 1
        .Cells.Clear
        Do Until rs.EOF
            For j = 0 To rs.Fields.Count - 1
                If i = 1 Then .Cells(i, j + 1) = rs(j).Name
                .Cells(i + 1, j + 1) = rs(j).Value
            Next j
            rs.MoveNext
            i = i + 1
        Loop
    End With
    
    rs.Close
    Set rs = Nothing
    
    cn.Close
    Set cn = Nothing
    
End Sub

Sub Sample_Delete()

'参照設定:Microsoft ActiveX Data Objects 6.1 Library

Dim cn As ADODB.Connection

Dim rs As ADODB.Recordset

Dim constr As String

Dim DBFile As String

Dim i As Long

Dim j As Long

DBFile = ActiveWorkbook.Path & "\mydb1.accdb"

constr = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & DBFile

Set cn = New ADODB.Connection

cn.ConnectionString = constr

cn.Open

Set rs = New ADODB.Recordset

With rs

'テーブルを開く

.Source = "テーブル1"

.ActiveConnection = cn

.CursorType = adOpenKeyset 'キーセットカーソル使用

.LockType = adLockPessimistic 'レコード単位排他的ロック

.Open

'ID=1 のレコードにカーソルを移動

.Find "ID = 1", 0, adSearchForward

'カレントレコードを削除

.Delete

End With

With Worksheets("Sheet1")

rs.MoveFirst

i = 1

.Cells.Clear

Do Until rs.EOF

For j = 0 To rs.Fields.Count - 1

If i = 1 Then .Cells(i, j + 1) = rs(j).Name

.Cells(i + 1, j + 1) = rs(j).Value

Next j

rs.MoveNext

i = i + 1

Loop

End With

rs.Close

Set rs = Nothing

cn.Close

Set cn = Nothing

End Sub

データベースのレコードを削除する

Delete メソッド

引数・戻り値

Delete メソッド 使用例

サンプルVBAソース

実行結果

Delete メソッド使用例