省略可能な引数・デフォルト値を設定（ Optional キーワード）

2015/04/29

Optional キーワード

Optional キーワードを使用するとプロシージャの引数を省略したり、引数を省略した場合の初期値を設定することができます。

【構文】

Sub name ( Optional varname [ As varname_type ] [ = default ] )

【項目の説明】

name ・・・定義するプロシージャ（Sub プロシージャ・Function プロシージャなど）の名前
varname ・・・プロシージャを呼び出したときに引き渡す引数を指定します。複数指定する場合はカンマ（,）で区切ります。
varname_type ・・・引数 varname のデータ型を指定します。省略すると引数 varname は、バリアント型（Variant）となります。
default ・・・プロシージャを呼び出した際、Optional キーワードが付けられた引数が省略された場合のデフォルト値を指定します。（省略可）
※ 引数 varname が、バリアント型（Variant）で、引数のデフォルト値 default が設定されていない場合は、IsMissing 関数を使って引数 varname が省略されたかどうかを判定することができます。

Optional キーワードのデフォルト値に設定できる値は、定数式のみで、オブジェクトを指定することはできません。

Optional キーワードの使用例

サンプルVBAソース

　
Sub Sample()

    'Sample_optional01
    Debug.Print Sample_optional01(1, 2, 3)      '引数すべてを設定
    Debug.Print Sample_optional01(1, , 3)       '2番目の引数を省略
    Debug.Print Sample_optional01(1, 2)         '3番目の引数を省略
    Debug.Print Sample_optional01(1)            '2番目、3番目の引数を省略
    
    'Sample_optional02
    Debug.Print Sample_optional02()             '引数省略
    Debug.Print Sample_optional02(25)           '引数に整数値を設定
    Debug.Print Sample_optional02(ActiveSheet)  '引数に「ActiveSheet」を設定

End Sub
'-------------------------------------------------------------------------------
'Optional キーワードを使った例
Function Sample_optional01(val1 As Integer, Optional val2 As Integer = 999, _
                           Optional val3 = "省略されました") As Variant

    If IsNumeric(val3) Then
        
        Sample_optional01 = val1 + val2 + val3
    
        Exit Function
    
    End If
    
    Sample_optional01 = val3

End Function
'-------------------------------------------------------------------------------
'オブジェクト型の引数
Function Sample_optional02(Optional obj) As String
    '※オブジェクト型の場合は、デフォルト値を設定することが出来ません
    
    'IsMissing 関数を使用して引数が省略されたかどうか確認
    If IsMissing(obj) Then
        Set obj = ActiveWorkbook
    End If
    
    '引数の型チェック（上記IsMissing 関数は、バリアント型でしか使用できないため）
    
    If VarType(obj) = vbObject Then
        
        Sample_optional02 = obj.Name
    
    Else
    
        Sample_optional02 = "引数が間違っています"

    End If

End Function